blog.ashier.com flash / flex / air development
rss rss comment
Wrapper Class for a RemoteObject

There are alot of ways to connect to a remote service in Flex / Flash.

You can do it tag based:

PLAIN TEXT
Actionscript:
  1. <mx:Application
  2.     xmlns:mx="http://www.adobe.com/2006/mxml"
  3.     layout="absolute">
  4.    
  5.     <mx:RemoteObject id="blazeService" fault="onFault(event)" source="hello.Hello" endpoint="http://localhost:8400/hello/messagebroker/amf/" destination="Hello">
  6.         <mx:method name="sayHello" result="onResult(event)" />
  7.     </mx:RemoteObject>
  8.  
  9.     <mx:Script>
  10.    
  11.         <![CDATA[
  12.             import mx.messaging.channels.AMFChannel;
  13.             import mx.rpc.events.ResultEvent;
  14.             import mx.rpc.events.FaultEvent;
  15.            
  16.             private function onResult(e:ResultEvent):void {
  17.                 trace("Result" + e.result);
  18.             }
  19.            
  20.             private function onFault(e:FaultEvent):void {
  21.                 trace("fault");
  22.             }
  23.         ]]>
  24.     </mx:Script>
  25.    
  26. </mx:Application>

or actionsript based:

PLAIN TEXT
Actionscript:
  1. <?xml version="1.0" encoding="utf-8"?>
  2. <mx:Application
  3.     xmlns:mx="http://www.adobe.com/2006/mxml"
  4.     layout="absolute"
  5.     creationComplete="onCreationComplete()">
  6.    
  7.     <mx:Script>
  8.         <![CDATA[
  9.             import mx.rpc.events.FaultEvent;
  10.             import mx.rpc.events.ResultEvent;
  11.             import mx.messaging.ChannelSet;
  12.             import mx.messaging.channels.AMFChannel;
  13.             import mx.rpc.remoting.RemoteObject;
  14.            
  15.             private var ro:RemoteObject;
  16.             private function onCreationComplete():void {
  17.                
  18.                 var channelSet:ChannelSet = new ChannelSet();
  19.                 var amfChannel:AMFChannel = new AMFChannel();
  20.                 ro = new RemoteObject();
  21.                
  22.                 ro.addEventListener(ResultEvent.RESULT, onResult);
  23.                 ro.addEventListener(FaultEvent.FAULT, onFault);
  24.                
  25.                 amfChannel.uri = "http://localhost:8400/hello/messagebroker/amf/";
  26.                 channelSet.channels = [amfChannel];
  27.                
  28.                 ro.channelSet = channelSet;
  29.                 ro.source = "hello.Hello";
  30.                 ro.destination = "Hello";
  31.                 ro.getOperation("sayHello").send();
  32.                
  33.             }
  34.            
  35.             private function onResult(e:ResultEvent):void {
  36.                 trace("Result" + e.result);
  37.             }
  38.            
  39.             private function onFault(e:FaultEvent):void {
  40.                 trace("fault");
  41.             }
  42.            
  43.         ]]>
  44.     </mx:Script>
  45.    
  46. </mx:Application>

But eventually, you'll be required to re-use the code. There are a lot of ways to do this. You may extend the RemoteObject Class or wrap it in another class. It's up to you to decide which way you want. Anyway..

Here's the wrapper class.

RemoteObjectWrapper.as

PLAIN TEXT
Actionscript:
  1. package {
  2.    
  3.     import flash.events.EventDispatcher;
  4.    
  5.     import mx.messaging.ChannelSet;
  6.     import mx.messaging.channels.AMFChannel;
  7.     import mx.rpc.events.FaultEvent;
  8.     import mx.rpc.events.ResultEvent;
  9.     import mx.rpc.remoting.RemoteObject;
  10.    
  11.     public class RemoteObjectWrapper extends EventDispatcher {
  12.        
  13.         public function RemoteObjectWrapper (endpoint:String = null) {
  14.             super();
  15.             if(endpoint) {
  16.                 _endpoint = endpoint;
  17.                 initializeRemoteObject();
  18.             }
  19.         }
  20.        
  21.         private var remoting:RemoteObject;
  22.         protected function initializeRemoteObject():void {
  23.             try {
  24.                 remoting = new RemoteObject();
  25.                 remoting.addEventListener(ResultEvent.RESULT, onResult);
  26.                 remoting.addEventListener(FaultEvent.FAULT, onFault);
  27.                
  28.                 var channelSet:ChannelSet = new ChannelSet();
  29.                 var amfChannel:AMFChannel = new AMFChannel();
  30.                 amfChannel.uri = _endpoint;
  31.                 channelSet.channels = [amfChannel];
  32.                 remoting.channelSet = channelSet;
  33.                 remoting.source = _source;
  34.                 remoting.destination = _destination;
  35.             }catch(e:Error) {}
  36.         }
  37.        
  38.         public function send(method:String, param:Object = null):void {
  39.             if(!remoting) {
  40.                 initializeRemoteObject();
  41.             }
  42.             if(param) {
  43.                 remoting.getOperation(method).send(param);
  44.             }else {
  45.                 remoting.getOperation(method).send();
  46.             }
  47.         }
  48.        
  49.         private function onResult(result:ResultEvent):void {
  50.             dispatchEvent(new RemoteObjectWrapperEvent(RemoteObjectWrapperEvent.RESULT, result.result));
  51.         }
  52.        
  53.         private function onFault(fault:FaultEvent):void {
  54.             dispatchEvent(new RemoteObjectWrapperEvent(RemoteObjectWrapperEvent.FAULT, fault.fault));
  55.         }
  56.        
  57.         private var _endpoint:String;
  58.         public function set endpoint(_g:String):void {
  59.             _endpoint = _g;
  60.         }
  61.        
  62.         public function get endpoint ():String {
  63.             return _endpoint;
  64.         }
  65.        
  66.         private var _destination:String;
  67.         public function set destination(_g:String):void {
  68.             _destination = _g;
  69.         }
  70.        
  71.         public function get destination ():String {
  72.             return _destination;
  73.         }
  74.        
  75.         private var _source:String;
  76.         public function set source(_g:String):void {
  77.             _source = _g;
  78.         }
  79.        
  80.         public function get source ():String {
  81.             return _source;
  82.         }
  83.        
  84.     }
  85. };

and the event:

RemoteObjectWrapperEvent.as

PLAIN TEXT
Actionscript:
  1. package {
  2.    
  3.     import flash.events.Event;
  4.    
  5.     public class RemoteObjectWrapperEvent extends Event {
  6.    
  7.         public static const RESULT:String = "result";
  8.         public static const FAULT:String = "fault";
  9.        
  10.         public var data:Object = new Object();
  11.        
  12.         public function RemoteObjectWrapperEvent (type:String, _data:Object){
  13.             super(type);
  14.             data = _data;
  15.         }
  16.  
  17.         override public function clone():Event {
  18.                return new RemoteObjectWrapperEvent(type, data);
  19.         }
  20.  
  21.     }
  22.  
  23. }

sample usage:

PLAIN TEXT
Actionscript:
  1. <?xml version="1.0" encoding="utf-8"?>
  2. <mx:Application
  3.     xmlns:mx="http://www.adobe.com/2006/mxml"
  4.     creationComplete="onCreationComplete()"
  5.     layout="absolute">
  6.    
  7.     <mx:Script>
  8.         <![CDATA[
  9.             import RemoteObjectWrapperEvent;
  10.             import RemoteObjectWrapper;
  11.            
  12.             private var ro:RemoteObjectWrapper;
  13.             private function onCreationComplete():void {
  14.                 ro = new RemoteObjectWrapper();
  15.                 ro.addEventListener(RemoteObjectWrapperEvent.RESULT, onResult);
  16.                 ro.addEventListener(RemoteObjectWrapperEvent.FAULT, onFault);
  17.                 ro.endpoint = "http://localhost:8400/hello/messagebroker/amf/";
  18.                 ro.source = "hello.Hello";
  19.                 ro.destination = "Hello";
  20.                
  21.                 ro.send("sayHello");
  22.                
  23.             }
  24.            
  25.             private function onResult(e:RemoteObjectWrapperEvent):void {
  26.                 trace("Result" + e.data);
  27.             }
  28.            
  29.             private function onFault(e:RemoteObjectWrapperEvent):void {
  30.                 trace("fault");
  31.             }
  32.            
  33.         ]]>
  34.     </mx:Script>
  35.    
  36. </mx:Application>

So, I think you see the difference. For me, having a wrapper class makes the code a lot more easy to understand, will lessen errors that might occur, and the nicest thing is you have a code that is easy to maintain.

If you don't want to add compiler options, this is the also one way to do it.

~ Ashier

Tags: , , , , ,

This entry was posted on Thursday, March 6th, 2008 at 8:41 pm and is filed under AMFPHP, Flash Remoting, Flex, Weborb. You can follow any responses to this entry through the RSS 2.0 feed. You can leave a response, or trackback from your own site.

6 Responses to “Wrapper Class for a RemoteObject”

  1. Aral Balkan Says:
    April 28th, 2008 at 12:52 am

    Hi Ashier,

    Unless I’m missing something, RemoteObject is Flex-only. I can’t believe that it’s not usable via pure AS3 and/or Flash 9. What were they thinking?

    Thank you for your support of Singularity, by the way :)

    Aral

  2. Ashier de Leon Says:
    April 28th, 2008 at 7:13 am

    Ooops… :) Thanks

  3. Rodrigo Says:
    July 3rd, 2008 at 11:19 pm

    Works! Thanks

  4. Igor RUSSIAN FEDERATION Says:
    August 2nd, 2008 at 7:39 am

    Great Thanks for this post!

  5. Richard NETHERLANDS Says:
    August 24th, 2008 at 1:35 am

    Thanks for the post - actually you can get RemoteObject working in AS3. I documented it here:

    http://yaa-blog.blogspot.com/2008/08/remoting-with-blazeds-from-plain.html

  6. nomoro encontros Says:
    August 15th, 2009 at 7:59 am

    Thank’s worked very nice with Singlethon Class.

Leave a Reply

© 2007 - 2008 Ashier de Leon. All rights reserved.
Powered by Wordpress. Hosted by Slicehost.